It's a generative art made with the Vector Field technique.

A generative art of random swirls.

An implementation of Vector Field by GenerateMe.

It's a generative art made with the 'Processing'.

This is yet another implementation of Vector Field written by GenerateMe. Just like the other work of mine 'High Voltage'.

Drawing vector field
https://generateme.wordpress.com/2016/04/24/drawing-vector-field/

It makes swirls randomly and I felt it looks like eyes.








 

The 'Processing' code example.

This code do not display any images on the screen but just generates image files.

Please feel free to use this example code of the 'Processing' under the terms of the GPL. To see other works based on my code is my pleasure. And my honor.


/**
 * Demon's Eye.
 * draw 3 custom noise vector field images each different color.
 * reference : https://generateme.wordpress.com/2016/04/24/drawing-vector-field/
 * 
 * @author @deconbatch
 * @version 0.1
 * Processing 3.2.1
 * 2019.03.02
 */

void setup() {

  size(980, 980);
  colorMode(HSB, 360, 100, 100, 100);
  smooth();
  noStroke();
  noLoop();

}

void draw() {
 
  int   plotCntMax = 1500;
  float plotDiv    = 0.0005;
  float baseHue    = random(360.0);

  for (int imgCnt = 1; imgCnt <= 3; ++imgCnt) {

    // shape parameters
    float paramA   = random(1.5, 4.5);
    float paramB   = random(1.5, 4.5);
    float paramC   = random(1.5, 4.5);
    float paramD   = random(1.5, 4.5);
    float plotMult = random(1.0, 4.0);

    float initDiv  = random(0.020, 0.025);
    float baseSiz  = initDiv * initDiv * 5000.0;
    float baseBri  = (1.6 - initDiv * 25) * 100;

    baseHue += 90.0; // 90 hue difference each image
    background(baseHue, 100.0, 10.0, 100);
    blendMode(SCREEN);

    // draw vector field
    for (float xInit = 0.2; xInit <= 0.8; xInit += initDiv) {
      for (float yInit = 0.2; yInit <= 0.8; yInit += initDiv) {
        float xPoint = xInit;
        float yPoint = yInit;
        for (int plotCnt = 0; plotCnt < plotCntMax; ++plotCnt) {

          float plotRatio = map(plotCnt, 0, plotCntMax, 0.0, 1.0);
          float eHue      = baseHue + plotRatio * 30.0 + customNoise(xInit, yInit) * 60.0;
          float eSat      = map(sin(PI * plotRatio), 0.0, 1.0, 100.0, 10.0);
          float eBri      = baseBri * (1.0 - sin(PI * plotRatio));
          float eSiz      = baseSiz * sin(PI * plotRatio);

          float xPrev = xPoint;
          float yPrev = yPoint;
          xPoint += plotDiv * cos(TWO_PI * customNoise(yPrev * paramA, yPrev * paramB) * plotMult);
          yPoint += plotDiv * cos(TWO_PI * customNoise(xPrev * paramC, xPrev * paramD) * plotMult);

          fill(eHue % 360.0, eSat, eBri, 100.0);
          ellipse(xPoint * width, yPoint * height, eSiz, eSiz);

        }
      }
    }
      
    casing();
    saveFrame("frames/" + String.format("%04d", imgCnt) + ".png");

  }

  exit();

}

/**
 * casing : draw fancy casing
 */
private void casing() {
  blendMode(BLEND);
  fill(0.0, 0.0, 0.0, 0.0);
  strokeWeight(60.0);
  stroke(0.0, 0.0, 0.0, 100.0);
  rect(0.0, 0.0, width, height);
  strokeWeight(50.0);
  stroke(0.0, 0.0, 100.0, 100.0);
  rect(0.0, 0.0, width, height);
  noStroke();
  noFill();
}

/**
 * customNoise : returns -1.0 .. 1.0 almost random but interesting value
 */
float customNoise(float _x, float _y) {
  return pow(sin(_x), 3) * cos(pow(_y, 2));
}

/*
Copyright (C) 2019- deconbatch

This program is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation; either version 3 of the License, or
(at your option) any later version.

This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program.  If not, see <http://www.gnu.org/licenses/>
*/


 

Yet another example images.

A generative art of random swirls.

A generative art of random swirls.

 

Next Post Previous Post
No Comment
Add Comment
comment url