The Vector Field High Voltage generator!

Description of this generative artwork.

This generative artwork was made with the code of the 'Processing'.

I used the idea of Vector Field written by GenerateMe. And I just changed the coordinates calculation formula in the other work of mine 'Daydream'.

Drawing vector field | GenerateMe
https://generateme.wordpress.com/2016/04/24/drawing-vector-field/

The calculation formula in my code is like below.

```xPoint += plotDiv * pow(sin(TWO_PI * customNoise(xInit * paramA, yPrev * paramB) * plotMult), 3);
yPoint += plotDiv * pow(cos(TWO_PI * customNoise(yInit * paramC, xPrev * paramD) * plotMult), 3);

/**
* customNoise : returns almost random but interesting value
*/
float customNoise(float _x, float _y) {
return pow(sin(_x), 3) * cos(pow(_y, 2));
}
```

The 'Processing' code example.

Please feel free to use this example code under the terms of the GPL.
To see other works based on my code is my pleasure. And my honor.

This example code does not display any images on the screen but just generates image files.

```/**
* High Voltage.
* draw 3 custom noise vector field images each different color.
* reference : https://generateme.wordpress.com/2016/04/24/drawing-vector-field/
*
* @author @deconbatch
* @version 0.1
* Processing 3.2.1
* 2019.03.01
*/

void setup() {

size(980, 980);
colorMode(HSB, 360, 100, 100, 100);
smooth();
noStroke();
noLoop();

}

void draw() {

int   plotCntMax = 3000;
float plotDiv    = 0.0005;
float baseHue    = random(360.0);

for (int imgCnt = 1; imgCnt <= 3; ++imgCnt) {

// shape parameters
float paramA   = random(5.0, 15.0);
float paramB   = random(5.0, 15.0);
float paramC   = random(5.0, 15.0);
float paramD   = random(5.0, 15.0);
float plotMult = random(2.0, 10.0);

float initDiv  = random(0.020, 0.025);
float baseSiz  = initDiv * initDiv * 5000.0;
float baseBri  = (1.6 - initDiv * 25) * 100;

baseHue += 120.0; // 120 hue difference each image
background(baseHue, 100.0, 10.0, 100);
blendMode(SCREEN);

// draw vector field
for (float xInit = 0.25; xInit <= 0.75; xInit += initDiv) {
for (float yInit = 0.25; yInit <= 0.75; yInit += initDiv) {
float xPoint = xInit;
float yPoint = yInit;
for (int plotCnt = 0; plotCnt < plotCntMax; ++plotCnt) {

float plotRatio = map(plotCnt, 0, plotCntMax, 0.0, 1.0);
float eHue      = baseHue + plotRatio * 60.0 + floor(((xInit * yInit) * 10000.0) % 7.0) * 5.0;;
float eSat      = map(sin(PI * plotRatio), 0.0, 1.0, 80.0, 30.0);
float eBri      = baseBri * (1.0 - sin(PI * plotRatio));
float eSiz      = baseSiz * sin(PI * plotRatio);

float xPrev = xPoint;
float yPrev = yPoint;
xPoint += plotDiv * pow(sin(TWO_PI * customNoise(xInit * paramA, yPrev * paramB) * plotMult), 3);
yPoint += plotDiv * pow(cos(TWO_PI * customNoise(yInit * paramC, xPrev * paramD) * plotMult), 3);

fill(eHue % 360.0, eSat, eBri, 100.0);
ellipse(xPoint * width, yPoint * height, eSiz, eSiz);

}
}
}

casing();
saveFrame("frames/" + String.format("%04d", imgCnt) + ".png");

}

exit();

}

/**
* casing : draw fancy casing
*/
private void casing() {
blendMode(BLEND);
fill(0.0, 0.0, 0.0, 0.0);
strokeWeight(60.0);
stroke(0.0, 0.0, 0.0, 100.0);
rect(0.0, 0.0, width, height);
strokeWeight(50.0);
stroke(0.0, 0.0, 100.0, 100.0);
rect(0.0, 0.0, width, height);
noStroke();
noFill();
}

/**
* customNoise : returns almost random but interesting value
*/
float customNoise(float _x, float _y) {
return pow(sin(_x), 3) * cos(pow(_y, 2));
}

/*

This program is free software: you can redistribute it and/or modify
the Free Software Foundation; either version 3 of the License, or
(at your option) any later version.

This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program.  If not, see <http://www.gnu.org/licenses/>
*/
```

No Comment